macro inter_sign arg1=2 arg2=3.2 arg3=1 arg4=0.4 arg5=1 arg6=45
*                 P.Ju 09-04-1997
*
* draws an interruption sign on an vertical or horizontal axis
* exec inter_sign 2 10 1 : draws /
*                               /  at x=2 cm y=10 cm on a vertical axix
* exec inter_sign 4 2 2 : draws // at x=4 y=2 on an horizontal axis
*    with default values: distance between the bars: 0.4 cm (4th argument)
*                         bar length: 1 cm (5th argument)
*                         bar angle: 45 degrees (6th argument)
*
selnt 1          | everything in cm!
x0=[arg1]        | x of center point 
y0=[arg2]        | y of  center point 
axis=[arg3]      | vertical or horizontal?
d=[arg4]         | distance between bars
r=[arg5]         | bar length
theta=[arg6]     | bar angle
d1= $sigma(([r]/2.)*cos(pi*[theta]/180.))
d2=$sigma(([r]/2.)*sin(pi*[theta]/180.))
*    vertical case 
if [axis]=1 then
   sigma x=array(4,[x0]-[d1]&[x0]+[d1]&[x0]+[d1]&[x0]-[d1])
   sigma y=array(4,[y0]+[d]/2-[d2]&[y0]+[d]/2+[d2]&_
                   [y0]-[d]/2+[d2]&[y0]-[d]/2-[d2])
else
*    horizontal case  
   sigma x=array(4,[x0]+[d]/2-[d1]&[x0]+[d]/2+[d1]&_
                  [x0]-[d]/2+[d1]&[x0]-[d]/2-[d1])
   sigma y=array(4,[y0]-[d2]&[y0]+[d2]&[y0]+[d2]&[y0]-[d2])
endif

set fais 1                         | surface is filled
set faci 0                         | surface is filled in white
farea 4 x y                        | fill parallelelogram
set plci 1                         | bars are drawn in black 
line $eval(x(1))  $eval(y(1)) $eval(x(2))  $eval(y(2)) | first bar
line $eval(x(4))  $eval(y(4)) $eval(x(3))  $eval(y(3)) | second bar
return